rembg: add

README.md

@@ -39,6 +39,13 @@ The main outputs of the `flake.nix` at the moment are as follows:
 
 ![invokeai](/../images/invokeai.webp)
 
+#### Rembg ( Automatic Background Remover )
+
+- `nix run .#rembg-cpu -- i input.png output.png`
+- `nix run .#rembg-cpu -- s --port 9226`
+
+![rembg UI](/../images/rembg.webp)
+
 ## Install NixOS-WSL in Windows
 
 If you're interested in running nixified.ai in the Windows Subsystem for Linux, you'll need to enable the WSL and then install NixOS-WSL via it. We provide a script that will do everything for you.

flake.nix

@@ -18,6 +18,10 @@
       url = "github:koboldai/koboldai-client/1.19.2";
       flake = false;
     };
+    rembg-src = {
+      url = "github:danielgatis/rembg/v2.0.50";
+      flake = false;
+    };
     flake-parts = {
       url = "github:hercules-ci/flake-parts";
       inputs.nixpkgs-lib.follows = "nixpkgs";
@@ -38,6 +42,7 @@
         ./modules/aipython3
         ./projects/invokeai
         ./projects/koboldai
+        ./projects/rembg
         ./website
       ];
   };

modules/aipython3/default.nix

@@ -18,6 +18,11 @@
         overlays.torchRocm
       ];
 
+      aipython3-cpu = mkPythonPackages [
+        overlays.fixPackages
+        overlays.extraDeps
+      ];
+
       aipython3-nvidia = mkPythonPackages [
         overlays.fixPackages
         overlays.extraDeps

modules/aipython3/overlays.nix

@@ -48,6 +48,8 @@ pkgs: {
     opencv-python-headless = final.opencv-python;
     opencv-python = final.opencv4;
 
+    asyncer = callPackage ../../packages/asyncer { };
+    pymatting = callPackage ../../packages/pymatting { };
     safetensors = callPackage ../../packages/safetensors { };
     compel = callPackage ../../packages/compel { };
     apispec-webframeworks = callPackage ../../packages/apispec-webframeworks { };

packages/asyncer/default.nix

@@ -0,0 +1,25 @@
+# WARNING: This file was automatically generated. You should avoid editing it.
+# If you run pynixify again, the file will be either overwritten or
+# deleted, and you will lose the changes you made to it.
+
+{ anyio, buildPythonPackage, fetchPypi, lib }:
+
+buildPythonPackage rec {
+  pname = "asyncer";
+  version = "0.0.2";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0czlyysclcs1lyqh5j3a3ak05jb1jys5sfdldgqbmsr66rgwhinm";
+  };
+
+  propagatedBuildInputs = [ anyio ];
+
+  # TODO FIXME
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Asyncer, async and await, focused on developer experience.";
+    homepage = "https://github.com/tiangolo/asyncer";
+  };
+}

packages/pymatting/default.nix

@@ -0,0 +1,26 @@
+# WARNING: This file was automatically generated. You should avoid editing it.
+# If you run pynixify again, the file will be either overwritten or
+# deleted, and you will lose the changes you made to it.
+
+{ buildPythonPackage, fetchPypi, lib, numba, numpy, pillow, scipy }:
+
+buildPythonPackage rec {
+  pname = "pymatting";
+  version = "1.1.8";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "PyMatting";
+    sha256 = "1k1aacqrpx03vh7d37vq9m40j6hmcfyf716jvwqni6bl13phhdd7";
+  };
+
+  propagatedBuildInputs = [ numpy pillow numba scipy ];
+
+  # TODO FIXME
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Python package for alpha matting.";
+    homepage = "https://pymatting.github.io";
+  };
+}

projects/rembg/default.nix

@@ -0,0 +1,37 @@
+{ config, inputs, lib, withSystem, ... }:
+
+{
+  perSystem = { config, pkgs, ... }:
+    let
+      inherit (config.dependencySets) aipython3-cpu;
+
+      src = inputs.rembg-src;
+
+      mkInvokeAIVariant = args: pkgs.callPackage ./package.nix ({ inherit src; } // args);
+    in
+    {
+      packages = {
+        rembg-cpu = mkInvokeAIVariant {
+          aipython3 = aipython3-cpu;
+        };
+      };
+    };
+
+  flake.nixosModules =
+    let
+      packageModule = pkgAttrName: { pkgs, ... }: {
+        services.rembg.package = withSystem pkgs.system (
+          { config, ... }: lib.mkOptionDefault config.packages.${pkgAttrName}
+        );
+      };
+    in
+    {
+      rembg = ./nixos;
+      rembg-cpu = {
+        imports = [
+          config.flake.nixosModules.rembg
+          (packageModule "rembg-cpu")
+        ];
+      };
+    };
+}

projects/rembg/package.nix

@@ -0,0 +1,56 @@
+{ aipython3
+, callPackage
+, src
+}:
+let
+  abseil-onnx = callPackage ./packages/abseil-onnx { };
+  microsoft-gsl = callPackage ./packages/microsoft-gsl { };
+  onnx-custom = callPackage ./packages/onnx { inherit aipython3; };
+  onnxruntime = callPackage ./packages/onnxruntime { inherit aipython3 microsoft-gsl onnx-custom; abseil-cpp = abseil-onnx; };
+  onnxruntime-pyt = callPackage ./packages/onnxruntime-python
+    { inherit aipython3 onnxruntime; };
+in
+
+aipython3.buildPythonPackage {
+  pname = "rembg";
+  format = "pyproject";
+  version = "2.0.50";
+  inherit src;
+  propagatedBuildInputs = with aipython3; [
+    numpy
+    onnxruntime-pyt
+    opencv4
+    pillow
+    pooch
+    pymatting
+    scikit-image
+    scipy
+    setuptools
+    tqdm
+
+    # {{{ cli deps
+    aiohttp
+    asyncer
+    click
+    fastapi
+    filetype
+    gradio
+    python-multipart
+    uvicorn
+    watchdog
+    # }}}
+  ];
+  nativeBuildInputs = [ aipython3.pythonRelaxDepsHook ];
+  pythonRemoveDeps = [ "clip" "pyreadline3" "flaskwebgui" "opencv-python" ];
+  pythonRelaxDeps = [ "dnspython" "protobuf" "flask" "flask-socketio" "pytorch-lightning" ];
+  postFixup = ''
+    chmod +x $out/bin/*
+    wrapPythonPrograms
+  '';
+  doCheck = false;
+  meta = {
+    description = "tool to remove image backgrounds";
+    homepage = "https://github.com/danielgatis/rembg/";
+    mainProgram = "rembg";
+  };
+}

projects/rembg/packages/abseil-onnx/default.nix

@@ -0,0 +1,35 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, static ? stdenv.hostPlatform.isStatic
+, cxxStandard ? null
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "abseil-cpp";
+  version = "20230125.3";
+
+  src = fetchFromGitHub {
+    owner = "abseil";
+    repo = "abseil-cpp";
+    rev = "refs/tags/${finalAttrs.version}";
+    hash = "sha256-PLoI7ix+reUqkZ947kWzls8lujYqWXk9A9a55UcfahI=";
+  };
+
+  cmakeFlags = [
+    "-DBUILD_SHARED_LIBS=${if static then "OFF" else "ON"}"
+  ] ++ lib.optionals (cxxStandard != null) [
+    "-DCMAKE_CXX_STANDARD=${cxxStandard}"
+  ];
+
+  nativeBuildInputs = [ cmake ];
+
+  meta = with lib; {
+    description = "An open-source collection of C++ code designed to augment the C++ standard library";
+    homepage = "https://abseil.io/";
+    license = licenses.asl20;
+    platforms = platforms.all;
+    maintainers = [ maintainers.andersk ];
+  };
+})

projects/rembg/packages/microsoft-gsl/default.nix

@@ -0,0 +1,37 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, gtest
+, pkg-config
+}:
+
+stdenv.mkDerivation rec {
+  pname = "microsoft-gsl";
+  version = "4.0.0";
+
+  src = fetchFromGitHub {
+    owner = "Microsoft";
+    repo = "GSL";
+    rev = "v${version}";
+    hash = "sha256-cXDFqt2KgMFGfdh6NGE+JmP4R0Wm9LNHM0eIblYe6zU=";
+  };
+
+  nativeBuildInputs = [ cmake pkg-config ];
+  buildInputs = [ gtest ];
+
+  doCheck = true;
+
+  meta = with lib; {
+    description = "C++ Core Guideline support library";
+    longDescription = ''
+      The Guideline Support Library (GSL) contains functions and types that are suggested for
+      use by the C++ Core Guidelines maintained by the Standard C++ Foundation.
+      This package contains Microsoft's implementation of GSL.
+    '';
+    homepage = "https://github.com/Microsoft/GSL";
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ thoughtpolice yuriaisaka ];
+  };
+}