Consult async-shell-command?

[mekeor]

I frequently use async-shell-command to start applications or do one-shot things. While that command does allow to browse history elements with M-n and M-p and even to search through the history with C-r (?), it does not show matching history elements while typing. Another aspect is that it'd be great if it would be showing matches from my shell history. That's why I wrote a thin wrapper around that command, called consult-sh. It's available on https://codeberg.org/mekeor/consult-sh. If you are interested, I can contribute it to consult.el. Here's the current source code for convenience:

;;; consult-sh.el --- Consulting async-shell-command -*- lexical-binding: t; -*-
;; Copyright (C) 2024 Free Software Foundation, Inc.
;; SPDX-License-Identifier: GPL-3.0-or-later
;; Version: 0.0.1
(defgroup consult-sh nil
  "Consulting async-shell-command."
  :group 'consult)

(defvar consult-sh-source-shell-command-history
  (list :name "shell-command-history"
        :history 'shell-command-history
        :narrow 'e
        :category 'sh
        :action #'async-shell-command
        :items (lambda () shell-command-history))
  "`shell-command-history' as source of shell-commands for `consult-sh'.")

(defvar consult-sh-source-bash-history
  (list :name "bash_history"
        :narrow 'b
        :category 'sh
        :action #'async-shell-command
        :items (lambda ()
                 (with-temp-buffer
                   ;; TODO: Be smart about path to Bash history.
                   (insert-file-contents "~/.bash_history")
                   (reverse-region (point-min) (point-max))
                   (split-string (buffer-string) "\n" t))))
  "Bash history as source of shell-commands for `consult-sh'.")

(defcustom consult-sh-sources
  (list 'consult-sh-source-shell-command-history
        'consult-sh-source-bash-history)
  "List of sources of shell-commands to be used by `consult-sh'."
  :group 'consult-sh
  :type '(repeat symbol))

(defun consult-sh ()
  "`async-shell-command' enhanced with display of matching history."
  (interactive)
  (let ((selected (consult--multi consult-sh-sources
                                  :prompt "Shell command: "
                                  :require-match nil
                                  :sort nil)))
    ;; When input did not match any candidate, call
    ;; `async-shell-command' on it nevertheless.
    (unless (plist-get (cdr selected) :match)
      (async-shell-command (car selected)))))

(provide 'consult-sh)

[ashlineldridge]

@mekeor, have you tried consult-history or cape-history? I use both with async-shell-command extensively.

[minad]

@ashlineldridge These are very good points. consult-history and cape-history can be used to enhance arbitrary minibuffer commands.

@mekeor I am not sure about adding consult-sh to Consult, since I'd like to keep some rough line around the feature set, such that we don't create a complete parallel word next to all the Emacs builtins. Consult mostly provides search-related completion commands, which are enhanced with preview and/or asynchronicity. Simple completion commands are not a good fit. Unfortunately a few commands made it into Consult before I got a better idea about what I think Consult should provide (e.g. consult-minor-mode or consult-kmacro do not fit so well). In the case of consult-sh you provide multiple sources, which is also another aspect provided by Consult. But there the line that I want to draw is that of buffer-related sources, usable by consult-buffer.

[mekeor]

@ashlineldridge, thanks for your comment. Yes, I'm aware of consult-history and enjoy it. consult-sh provides two advantages:

1. It's less to type. It's as if consult-sh is just like invoking async-shell-command and consult-history right after one another. (But also, you won't need the final double-RET.) So, in a sense, consult-sh is just a instantly-history-displaying, thin extension of async-shell-command.

2. consult-sh also provides Bash history as another source for history.

---

@minad, thanks for the feedback. I'm fine with consult-sh not being merged into Consult.

I wonder if there are Emacs core commands other than async-shell-command that would also benefit from "instant-history-displaying". (If so, it may be worth considering to create a package for that scope.)

[mekeor]

I did not try cape-history. I guess it could be used with consult-completion-in-region or similar to make matches show in the minibuffer (which I prefer instead of child frames (à la Corfu) in this context). It seems to me that it doesn't have benefits over consult-history here.

[minad]

@mekeor

I wonder if there are Emacs core commands other than async-shell-command that would also benefit from "instant-history-displaying". (If so, it may be worth considering to create a package for that scope.)

FWIW I think almost all read-from-minibuffer commands would profit from instant history. Iirc the eww command got recently extended like this. The reason why this hasn't been implemented pervasively in Emacs is the default completion UI, which wouldn't profit from this. As a workaround minibuffer-complete-history was added - not a good addition if you ask me.

If you are willing to hack something you could maybe try to advise read-from-minibuffer somehow, such that it gets automatically upgraded to history completion, if not already present.

[mekeor]

Thanks for the insights.

I most likely spend the time needed for hacking instant history into read-from-minibuffer (as a global feature).