build.gradle

buildscript {
    ext {
        grailsVersion = project.grailsVersion
    }
    repositories {
        mavenLocal()
        maven { url "https://repo.grails.org/grails/core" }
    }
    dependencies {
        classpath "org.grails:grails-gradle-plugin:$grailsVersion"
        classpath "com.bertramlabs.plugins:asset-pipeline-gradle:2.15.1"
    }
}

def setIfNotSet = { String name, value ->
    if (!project.ext.has(name)) {
        project.ext[name] = value
    }
}
setIfNotSet 'issueTrackerUrl', project.vcsUrl + '/issues'
setIfNotSet 'websiteUrl', project.vcsUrl

version "1.2.1.BUILD-SNAPSHOT"
group = 'org.grails.plugins'

apply plugin:"eclipse"
apply plugin: "idea"
apply plugin: "org.grails.grails-plugin"
apply plugin: "org.grails.grails-plugin-publish"
apply plugin: "org.grails.grails-gsp"
apply plugin: "asset-pipeline"

ext {
    grailsVersion = project.grailsVersion
    gradleWrapperVersion = project.gradleWrapperVersion
}

repositories {
    mavenLocal()
    maven { url "https://repo.grails.org/grails/core" }
}

dependencyManagement {
    imports {
        mavenBom "org.grails:grails-bom:$grailsVersion"
    }
    applyMavenExclusions false
}

dependencies {
    console "org.grails:grails-console"

    profile "org.grails.profiles:web-plugin"

    provided 'javax.servlet:javax.servlet-api:3.1.0'
    provided 'org.grails:grails-dependencies'
    provided 'org.grails.plugins:spring-security-core:3.2.+'
    provided 'org.grails.plugins:spring-security-oauth2:1.2.0'
    provided "org.grails:grails-plugin-services"

    runtime "com.bertramlabs.plugins:asset-pipeline-grails:2.15.1"

    testCompile "cglib:cglib-nodep:2.2.2"
    testCompile "org.grails:grails-plugin-testing"
    testCompile "org.grails:grails-web-testing-support"
}

task wrapper(type: Wrapper) {
    gradleVersion = gradleWrapperVersion
}

grailsPublish {
    user = System.getProperty("BINTRAY_USER")
    key = System.getProperty("BINTRAY_KEY")
    githubSlug = 'grails-plugins/grails-spring-security-oauth2-google'
    license {
        name = 'Apache-2.0'
    }
    title = "Spring Security Oauth2 Google Provider"
    desc = "This plugin provides the capability to authenticate via g+-oauth provider. Depends on grails-spring-security-oauth2. v1.2.0 starts after fork to grails-plugins org. Includes unreleased 1.1.1 from other repo."
    developers = [MatrixCrawler: "Johannes Brunswicker",
                  rvanderwerf   : "Ryan Vanderwerf"]
    userOrg = 'grails'
}

assets {
    packagePlugin = true
}