build.gradle

plugins {
	id 'maven-publish'
	id 'fabric-loom' version '1.7-SNAPSHOT' apply false


	// https://github.com/ReplayMod/preprocessor
	// https://github.com/Fallen-Breath/preprocessor
	id 'com.replaymod.preprocess' version '20c7ec554a'


}

preprocess {

	def mc116      = createNode('1.16.5'  , 1_16_05, 'yarn')
	def mc117      = createNode('1.17.1'  , 1_17_01, 'yarn')
	def mc118      = createNode('1.18.2'  , 1_18_02, 'yarn')
	def mc119      = createNode('1.19.4'  , 1_19_04, 'yarn')
	def mc120_1    = createNode('1.20.1'  , 1_20_01, 'yarn')
	def mc121      = createNode('1.21'  , 1_21_00, 'yarn')

	mc121.link(mc120_1, null)
	mc120_1.link(mc119, null)
	mc119.link(mc118, null)
	mc118.link(mc117, null)
	mc117.link(mc116, null)


}

tasks.register('buildAndGather') {
	subprojects {
		dependsOn project.tasks.named('build').get()
	}
	doFirst {
		println 'Gathering builds'
		def buildLibs = {
			p -> p.buildDir.toPath().resolve('libs')
		}
		delete fileTree(buildLibs(rootProject)) {
			include '*'
		}
		subprojects {
			copy {
				from(buildLibs(project)) {
					include '*.jar'
					exclude '*-dev.jar', '*-sources.jar'
				}
				into buildLibs(rootProject)
				duplicatesStrategy DuplicatesStrategy.INCLUDE
			}
		}
	}
}