Idea: Isolate variables from cell dependencies

[JohannesNE]

This is similar to #298

In interactive notebooks, it would be useful to hold back expensive computation until all parameters are set. The user could then press a button to update the dependent cells.

In R Shiny this is handled by "isolating" variables. Changing an isolated variable does not cause a reevaluation of the (reactive) variables that depend on them. (https://shiny.rstudio.com/articles/isolation.html)

Would it be possible to do something similar in Pluto?

In the example below I imagine that the isolate() function will make Pluto ignore 🐶 and 🐱 when making the dependency graph.
Only pressing the Update button will rerun the cell.

(Bonus points if outdated cells can be highlighted)

# ╔═╡ fc99521c-7eae-11ea-269b-0d124b8cbe48
begin
	dog_slider = @bind 🐶 html"<input type=range>"
	cat_slider = @bind 🐱 html"<input type=range>"
	
	md"""
	**How many pets do you have?**
	
	Dogs: $(dog_slider)
	
	Cats: $(cat_slider)
	"""
end

# ╔═╡ 52e15b49-4d02-43b5-994f-9f9d67ff53b4
@bind update html"<input type=button value='Update'>"

# ╔═╡ 500db9be-4562-442a-b33a-5dc7ae4dee0b
isolate(x) = x 

# ╔═╡ 1cf27d7c-7eaf-11ea-3ee3-456ed1e930ea
begin
	update

	n_dogs = isolate(🐶)	
	n_cats = isolate(🐱)
	
	md"""
	You have $(n_dogs) dogs and $(n_cats) cats!
	"""
end

[MichaelHatherly]

A while ago a hacked together something that kind of does what I think you're wanting:

macro isolate(var)
	return :(getfield(current_module(), $(Meta.quot(var))))
end

function current_module()
	id = PlutoRunner.moduleworkspace_count[]
	ws = Symbol("workspace#$id")
	return getfield(PlutoRunner.computer_workspace, ws)
end

and then use with

begin
	update

	n_dogs = @isolate(🐶)	
	n_cats = @isolate(🐱)
	
	md"""
	You have $(n_dogs) dogs and $(n_cats) cats!
	"""
end

Obviously it's a hack, but some official way to isolate variables like that would be nice. Maybe there's already a nice way to do this with the Disable cell feature?

[JohannesNE]

Cool. That works!... at least for my use case.

I'm not familiar with the inner workings of Pluto, and therefore do not know what makes this solution "hacky".

Not used to the GH discussions; should I mark this as an answer, or wait and see if there is some general interest in an official solution?

[MichaelHatherly]

Rather leave it unmarked until we get some feedback from the core devs. The solution I gave was hacky since it relies of tricking the code analysis that Pluto does to break the "link" between the var given to @isolate and the variable that it gets assigned to, and the current_module function relies on Pluto internals.

[fonsp]

You can also use:

macro isolate(var)
	return :(eval($(Meta.quot(var))))
end

which should be slightly more future-proof because it does not use pluto internals.

[JohannesNE]

The Wiki states that

In Pluto, assignments to values (e.g. a = 1) will 'trigger' reactivity, but assignments to properties (e.g. a.start = 2 or a[5] = 3) will not. This means that you can use a Ref (docs) to create 'non-reactive' variables.

Does this mean that a Ref() can solve this?
(I could not make it work by *randomly wrapping variables in Ref() 🤷 )

[MichaelHatherly]

Requires a couple extra steps with a Ref but is doable:

# ╔═╡ d351e33a-65a9-4ecf-84ce-48c8a4fc8984
using PlutoUI

# ╔═╡ edc9a6b7-eaa7-4f50-bcb0-2d4b30ff9bf4
begin
	dog_slider = @bind 🐶 html"<input type=range>"
	cat_slider = @bind 🐱 html"<input type=range>"
	
	md"""
	**How many pets do you have?**
	
	Dogs: $(dog_slider)
	
	Cats: $(cat_slider)
	"""
end

# ╔═╡ fdd3ecdc-4661-43ed-a6cc-63b9cb1a6dd4
@bind update html"<input type=button value='Update'>"

# ╔═╡ 35869c9c-0158-4dfe-a9d9-cde83a2ded64
dog_ref = Ref{Any}(nothing)

# ╔═╡ 66a804f8-29b7-4f2d-8d75-1027d8c438f2
cat_ref = Ref{Any}(nothing)

# ╔═╡ 953c15d2-35b8-4037-aab3-70e0b46378de
dog_ref[] = 🐶

# ╔═╡ 93e1b069-2c3d-4b0e-971a-e87e01a297b6
cat_ref[] = 🐱

# ╔═╡ de15e63a-f324-4936-9de4-97c683f0fc79
begin
	update

	n_dogs = dog_ref[]
	n_cats = cat_ref[]
	
	md"""
	You have $(n_dogs) dogs and $(n_cats) cats!
	"""
end

[JohannesNE]

Ahh, so you need to initiate the Ref first, because then assignment to this Ref does not trigger reactivity (as with structs). I think a dedicated macro is still relevant :)

[fonsp]

I'm marking this as the answer because it is the most official! Will be supported forever :)

[fonsp]

The answers by @MichaelHatherly are great! Those should answer your question for now.

I created a new discussion item with something that we have been discussing on the weekly pluto developers call (18:00 Thursday Berlin time, everyone is welcome!): #1743