SNTP lost configured servers after IP refresh

[MikeCley]

I have a ESP32-wroom and testing how it works with SNTP. DHCP provides first server and two more fall back servers in configuration.
I see that after IP address lease expired SNTP configuration lost 2 of 3 servers and if first server is unavailable then time can not be synchronized at all.
Is it a bug? Or i do it in a wrong way?
Lease expiration 5 minutes. SNTP on 10.64.1.1 down.

#include <esp_sntp.h>
#include <WiFi.h>
#include "esp_netif.h"
#include "esp_netif_sntp.h"

void time_sync_notification_cb(struct timeval* tv) {
  Serial.println("Synced");
  //esp_sntp_servermode_dhcp(0);
}

void setup() {
  Serial.begin(115200);
  Serial.printf("CONFIG_LWIP_SNTP_MAX_SERVERS: %i", CONFIG_LWIP_SNTP_MAX_SERVERS);

  esp_sntp_config_t config = ESP_NETIF_SNTP_DEFAULT_CONFIG_MULTIPLE(2, ESP_SNTP_SERVER_LIST("10.17.1.1", "10.17.1.8"));
  config.start = false;                      // start SNTP service explicitly (after connecting)
  config.server_from_dhcp = true;            // accept NTP offers from DHCP server, if any (need to enable *before* connecting)
  config.renew_servers_after_new_IP = true;  // let esp-netif update configured SNTP server(s) after receiving DHCP lease
  config.index_of_first_server = 1;          // updates from server num 1, leaving server 0 (from DHCP) intact
  // configure the event on which we renew servers
  config.ip_event_to_renew = IP_EVENT_STA_GOT_IP;
  config.sync_cb = time_sync_notification_cb;  // only if we need the notification function

  WiFi.begin("SSID", "password");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  Serial.println(WiFi.localIP());
  Serial.println("Connected");

  setenv("TZ", "<+03>-3", 1);
  tzset();

  // Can not init before connected - error
  esp_netif_sntp_init(&config);
  esp_sntp_set_sync_interval(1 * 60 * 1000);
  esp_netif_sntp_start();

    // Get DHCP 42 option
  WiFi.reconnect();
}

void print(uint8_t index) {
  const ip_addr_t* address = esp_sntp_getserver(index);
  uint32_t a = address->u_addr.ip4.addr;
  const uint32_t *a6 = address->u_addr.ip6.addr;
  const char* name = esp_sntp_getservername(index);
  name = name == 0 ? "n/a" : name;
  Serial.printf("esp_sntp_getserver(%i): %d %d.%d.%d.%d (%d:%d:%d:%d:%d), sntp_getservername(%i): %s, sntp_getreachability(%i): %d\r\n", index,
                address->type, a & 0xFF, (a >> 8) & 0xFF, (a >> 16) & 0xFF, (a >> 24) & 0xFF, a6[0], a6[1], a6[2], a6[3], address->u_addr.ip6.zone, index, name, index, esp_sntp_getreachability(index));
}

char sname[3][50];
uint32_t saddress[3];
uint8_t sreachability[3];

bool equals(uint8_t index) {
  const ip_addr_t* address = esp_sntp_getserver(index);
  uint32_t a = address->u_addr.ip4.addr;
  const char* name = esp_sntp_getservername(index);
  uint8_t reachability = esp_sntp_getreachability(index);

  if (a != saddress[index]
      || (name != 0 && strcmp(sname[index], name) != 0)
      || (name == 0 && sname[index][0] != 0)
      || sreachability[index] != reachability) {
    if (name != 0) {
      strcpy(sname[index], name);
    } else {
      sname[index][0] = 0;
    }
    saddress[index] = a;
    sreachability[index] = reachability;
    return false;
  } else {
    return true;
  }
}

void loop() {
  bool hasChanges = false;
  for (uint8_t index = 0; index < 3; index++) {
    hasChanges |= !equals(index);
  }
  if (hasChanges) {
    tm timeInfo;
    getLocalTime(&timeInfo);
    Serial.printf("Loop %d.%02d.%02d %02d:%02d:%02d\r\n", timeInfo.tm_year + 1900, timeInfo.tm_mon + 1, timeInfo.tm_mday, timeInfo.tm_hour, timeInfo.tm_min, timeInfo.tm_sec);
    for (uint8_t si = 0; si < 3; si++) {
      print(si);
    }
  }
  delay(1000);
}

...
CONFIG_LWIP_SNTP_MAX_SERVERS: 3.
10.64.1.14
Connected
Loop 1970.01.01 03:00:05
esp_sntp_getserver(0): 0 10.64.1.1 (16859146:0:0:0:0), sntp_getservername(0): n/a, sntp_getreachability(0): 0
esp_sntp_getserver(1): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(1): 10.17.1.1, sntp_getreachability(1): 0
esp_sntp_getserver(2): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(2): 10.17.1.8, sntp_getreachability(2): 0
...
Synced
Loop 2024.10.15 19:28:01
esp_sntp_getserver(0): 0 10.64.1.1 (16859146:0:0:0:0), sntp_getservername(0): n/a, sntp_getreachability(0): 0
esp_sntp_getserver(1): 0 10.17.1.1 (16847114:1073427580:-2146509924:1073427504:36), sntp_getservername(1): 10.17.1.1, sntp_getreachability(1): 1
esp_sntp_getserver(2): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(2): 10.17.1.8, sntp_getreachability(2): 0
...
Synced
Loop 2024.10.15 19:32:02
esp_sntp_getserver(0): 0 10.64.1.1 (16859146:0:0:0:0), sntp_getservername(0): n/a, sntp_getreachability(0): 0
esp_sntp_getserver(1): 0 10.17.1.1 (16847114:-1287651329:-2146540476:1073427536:28), sntp_getservername(1): 10.17.1.1, sntp_getreachability(1): 31
esp_sntp_getserver(2): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(2): 10.17.1.8, sntp_getreachability(2): 0
Loop 2024.10.15 19:32:45
esp_sntp_getserver(0): 0 10.64.1.1 (16859146:0:0:0:0), sntp_getservername(0): n/a, sntp_getreachability(0): 0
esp_sntp_getserver(1): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(1): n/a, sntp_getreachability(1): 31
esp_sntp_getserver(2): 0 0.0.0.0 (0:0:0:0:0), sntp_getservername(2): n/a, sntp_getreachability(2): 0