build.gradle

plugins {
    id "cpp"
    id "visual-studio"
    id "jaci.openrio.gradle.GradleRIO" version "2018.01.20"
}

def TEAM = 1771

// Define my targets (RoboRIO) and artifacts (deployable files)
// This is added by GradleRIO's backing project EmbeddedTools.
deploy {
    targets {
        target("roborio", jaci.openrio.gradle.frc.RoboRIO) {
            team = TEAM
        }
    }
    artifacts {
        artifact('frcNative', jaci.openrio.gradle.frc.FRCNativeArtifact) {
            targets << "roborio"
            component = 'frcUserProgram'
        }
    }
}

// Defining my C++ project. In this case, it is called 'frcUserProgram',
// and is of the language C++.
model {
    components {
        frcUserProgram(NativeExecutableSpec) {
            // Target the RoboRIO (arm-frc-linux-gnueabihf)
            targetPlatform 'roborio'
            sources.cpp {
                // This is where our source files are located (src/cpp for C++ files, src/include for headers)
                source {
                    srcDirs = ['src/cpp']
                    include '**/*.cpp'
                }
                exportedHeaders{
                    srcDirs = ['src/cpp', 'src/include']
                    include '**/*.hpp', '**/*.h'
                }

                // Define my dependencies. In this case, WPILib (+ friends), CTRE Phoenix (Talon SRX) and NavX.
                lib library: "wpilib"
                lib library: "ctre"
                lib library: "navx"
                lib library: "openrio.powerup.matchData"
            }
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.4'
}